Excel : comment trouver la valeur minimale en fonction de critères

Tutoriel Excel : comment trouver la valeur minimale en fonction de critères

Ce tutoriel Excel explique comment utiliser la fonction MIN, comment rechercher la valeur la plus petite par une condition et comment mettre en surbrillance le nombre minimum dans une plage de cellules.

MIN est l'une des fonctions Excel les plus simples et les plus faciles à utiliser dans Microsoft Excel. Cependant, il existe quelques astuces que vous devez connaître, et qui vous donneront de très gros avantages.

Comment utiliser la fonction MIN avec des conditions ? Comment extraire la plus petite valeur en ignorant les zéros ? …

Ce tutoriel fournit des réponses à ces questions en présentant plusieurs solutions pour accomplir ces tâches et d'autres tâches connexes.

Table des matières

Fonction MIN - exemples de syntaxe et d'utilisation dans Excel

Exemples d'utilisation de la formule MIN

Exemple 1. Recherche de la valeur la plus petite

Exemple 2. Recherche de la date la plus ancienne

Exemple 3. Récupération d'un minimum absolu

Trouver la valeur minimale en utilisant les critères dans Excel

Syntaxe et arguments des formules imbriquées MIN SI

Trouver le minimum en fonction d'une condition

Trouver la valeur la plus petite en ignorant les zéros

Mettre en surbrillance le plus petit nombre dans Excel

Minimum si plusieurs critères

Fonction MIN - exemples de syntaxe et d'utilisation dans Excel

La fonction MIN est une fonction intégrée dans Excel qui est classée comme une fonction statistique. Elle peut donc être utilisée comme fonction de feuille de calcul dans Excel.

En tant que fonction de feuille de calcul, la fonction MIN peut être entrée dans le cadre d'une formule dans une cellule. La syntaxe de la fonction MIN dans Microsoft Excel est comme suit :

MIN(nombre1; [nombre2 ; ... nombre_n])

Où :

nombre1 et nombre2 sont les arguments utilisés pour la fonction MIN, où « Nombre1 » est obligatoire et les valeurs suivantes sont facultatives.

  • Dans MS Excel 2007 et les versions ultérieures, nous pouvons fournir jusqu'à 255 arguments numériques à la fonction MIN. Cependant, dans Excel 2003 et les versions antérieures, il ne peut accepter que 30 arguments numériques.

Notes complémentaires :

  • Les arguments qui sont des valeurs d'erreur ou du texte qui ne peut pas être traduit en nombres provoquent des erreurs.
  • Les arguments peuvent être des nombres ou des noms, des tableaux ou des références contenant des nombres.
  • Les valeurs logiques et les représentations textuelles des nombres que vous saisissez directement dans la liste d'arguments sont comptées.
  • Si un argument est un tableau ou une référence, seuls les nombres de ce tableau ou référence sont utilisés. Les cellules vides, les valeurs logiques ou le texte du tableau ou de la référence sont ignorés.
  • Si les arguments ne contiennent aucun nombre, la fonction MIN renvoie 0 (zéro).
  • La principale différence entre la fonction MIN et la fonction « MINA » est que MINA évalue les valeurs « VRAI » et « FAUX » comme « 1 » et « 0 », respectivement. Par conséquent, si nous souhaitons inclure des valeurs logiques, nous devons utiliser la fonction MINA.

Exemples d'utilisation de la formule MIN

Examinons quelques exemples de la fonction MIN et explorons comment l’utiliser en tant que fonction de feuille de calcul dans Microsoft Excel :



Exemple 1. Recherche de la valeur la plus petite

Admettons que vous avez un tableau de notes des élèves. Votre tâche est de trouver la note la plus basse dans la classe. Vous avez plusieurs façons de procéder :

Méthode 1 : Entrez chaque chiffre de la colonne « Notes » directement dans la formule :

=MIN(10; 15; 15; 12; 10; 17; 18; 16; 16; 17; 10)

Méthode 2 : référencez les cellules de la colonne « Notes » une par une :

=MIN(B2; B3; B4; B5; B6; B7; B8; B9; B10; B11; B12; B13; B14)

Méthode 3 : référencez simplement toute la plage :

=MIN(B2:B14)

Méthode 4 : vous pouvez également créer une plage nommée et l'utiliser à la place pour éviter toute référence directe :

=MIN(Notes)

Exemple 2. Recherche de la date la plus ancienne

Si, par exemple, vous avez une liste de données dans une plage A1:A5 contenant des dates et que vous souhaitiez obtenir la date la plus ancienne parmi ces dates, comment y parvenir ?  Vous pouvez alors utiliser une formule basée sur la fonction MIN.

Appliquez la formule et sélectionnez les dates, en référençant directement la plage :

=MIN(A2:A5)

Ou la plage nommée :

=MIN(Dates)

Exemple 3. Récupération d'un minimum absolu

Dans Excel, nous pouvons utiliser la fonction MIN pour trouver les valeurs les plus petites dans une plage de cellules. Mais dans le cas où votre feuille de calcul est remplie de nombres positifs et négatifs, et que vous devez trouver les valeurs absolues minimales, la fonction MIN ne vous sera pas utile.

Que faire dans un tel cas ? Il existe une solution pour toute tâche dans Excel.

La solution que vous pouvez utiliser pour cette tâche particulière est appelée « fonction ABS », qui renvoie la valeur absolue des nombres que vous spécifiez. Ainsi, la combinaison des fonctions MIN et ABS fera l'affaire.

La petite formule matricielle suivante peut vous aider à trouver la plus petite valeur absolue :

  1. Dans une cellule vide, entrez cette formule =MIN(ABS(A1:A9)). Voir la capture d'écran ci-dessous :

  1. Appuyez ensuite sur les touches « Ctrl + Shift + Entrée», et la plus grande valeur absolue sera affichée dans la cellule.

Remarque : Dans la formule ci-dessus, A1:A9 est la plage dans laquelle vous souhaitez sélectionner la valeur la plus petite. Vous pouvez la changer selon vos besoins.

Trouver la valeur minimale en utilisant les critères dans Excel

Pour renvoyer la valeur la plus petite d'une plage de cellules, nous utilisons la fonction Excel MIN. Mais, si nous devons obtenir la valeur minimale en fonction de critères, Excel n'a pas de fonction intégrée pour cette mission. Cependant, nous pouvons renvoyer la valeur minimale si les critères correspondent en utilisant les fonctions MIN et SI ensemble dans une formule matricielle.

Le travail de chaque partie de la formule est comme suit :

  • La fonction MIN trouve la plus petite valeur dans la plage choisie.
  • La fonction SI nous permet de mettre en place une condition qui doit être vérifiée dans le résultat de la fonction MIN.
  • La formule matricielle permet à la fonction SI de tester plusieurs conditions dans une seule cellule et, lorsque la condition est remplie, la formule matricielle détermine les données que la fonction MIN examine pour trouver la valeur la plus petite.

Syntaxe et arguments des formules imbriquées MIN SI

La syntaxe de la formule MIN SI est comme suit :



=MIN(SI(test_logique ; valeur_si_vrai ; valeur_si_faux))

Étant donné que la fonction SI est imbriquée dans la fonction MIN, la fonction SI entière devient le seul argument de la fonction MIN.

Les arguments de la fonction SI sont :

  •  test_logique (obligatoire) : valeur ou expression testée pour déterminer si elle est vraie ou fausse.
  • valeur_si_vrai (obligatoire) : la valeur qui s'affiche si le « test_logique » est vrai.
  • valeur_si_faux (facultatif) : la valeur qui s'affiche si le « test_logique » est faux.

Trouver le minimum en fonction d'une condition

Dans cet exemple, nous devons obtenir la valeur minimale du Temps pris dans un tour (tour le plus rapide) par un conducteur spécifié comme valeur de critère. La plage de critères contenant les noms des conducteurs est « A2:A10 », la valeur de critère est donnée dans la cellule « E3 » et la plage de valeurs est « C2:C10 ».

En utilisant la formule ci-dessous, vous pouvez obtenir la valeur minimale qui vérifie le critère.

=MIN(SI($A$2:$A$10 = E3; $C$2:$C$10))

N’oubliez pas d’appuyer sur les touches « Ctrl + Shift + Entrée » pour en faire une formule matricielle.

Copiez ou faites glisser la poignée de recopie vers le bas pour obtenir les résultats pour d'autres valeurs de critères.

Trouver la valeur la plus petite en ignorant les zéros

Parfois, il est nécessaire de trouver le nombre minimum dans une plage tout en excluant les zéros.

La fonction MIN fonctionne non seulement avec des nombres positifs et négatifs, mais aussi avec des zéros. Si vous ne voulez pas que les zéros soient ce minimum, vous avez besoin de l'aide de la fonction SI. Une fois que vous ajoutez la limitation selon laquelle votre plage doit être supérieure strictement à zéro, le résultat attendu sera toujours différent de 0. Voici un exemple de la formule qui renvoie la valeur minimale en ignorant les zéros :

{=MIN(SI(A2:A10> 0; A2:A10))}    

Vous devez avoir remarqué les accolades autour de la formule matricielle. N'oubliez pas que vous ne les saisissez pas manuellement. Ils apparaissent lorsque vous appuyez sur les touches « Ctrl + Shift + Entrée » de votre clavier.

Mettre en surbrillance le plus petit nombre dans Excel

Et si vous n'avez pas besoin de renvoyer le plus petit chiffre, mais que vous voulez le trouver dans votre tableau ? La façon la plus simple de guider votre œil vers cette cellule est de la mettre en évidence. Ainsi, le moyen le plus simple de le faire est d'appliquer une mise en forme conditionnelle. C'est encore plus simple que d'écrire des fonctions :

  1. Sélectionnez la plage de cellule dans laquelle vous souhaitez mettre en surbrillance la valeur minimale. Dans cet exemple, sélectionnez les cellules B2 :B14.
  2. Créez une nouvelle règle de mise en forme conditionnelle en cliquant sur « Mise en forme conditionnelle »-> « Nouvelle règle ».

  1. Une fois la boîte de dialogue « Nouvelle règle de mise en forme» est ouverte, sélectionnez le type de règle « Appliquer une mise en forme uniquement aux valeurs rangées parmi les premières ou les dernières valeurs » :



  1. Étant donné que la tâche consiste à mettre en surbrillance le seul et unique chiffre le plus petit, choisissez l'option « Derniers »dans la liste déroulante et définissez « 1 » comme nombre de cellules à mettre en évidence.

Mais que faire s'il y a à nouveau un zéro dans votre tableau ? Comment ignorer les zéros lors de la mise en évidence du plus petit nombre ? Ne vous inquiétez pas, il y’a une autre solution :

  1. Créez une nouvelle règle de mise en forme conditionnelle en sélectionnant l'option « Utiliser une formule pour déterminer pour quelles cellules le format sera appliqué».

  1. Entrez la formule suivante dans le champ « Appliquer une mise en forme aux valeurs pour lesquelles cette formule est vraie» : =B2=MIN(SI($B$2:$B$14> 0; $B$2:$B$14)). Où B2 est la première cellule de la plage dans laquelle on veut mettre en évidence le nombre le plus petit :

  1. Définissez la couleur (Format… -> Remplissage) et appuyez sur OK.

Minimum si plusieurs critères

Lorsque vous travaillez avec de longues plages de données, vous devez peut-être trouver la valeur minimale dans la plage où plusieurs conditions correspondent. En termes simples, trouver la valeur minimale à l'aide de plusieurs fonctions SI. La fonction SI renvoie Vrai ou Faux et la fonction MIN recherche la valeur minimale dans le tableau correspondant.

Syntaxe pour trouver le minimum avec plusieurs critères :

{=MIN(SI(plage1 = critère1); SI(Plage2 = critère2; plage_min))}

Tout cela peut être difficile à comprendre. Alors, testons cette formule en l'exécutant sur l'exemple ci-dessous.

Exemple :

Ici, nous allons appliquer la formule pour trouver le prix minimum du produit dans la région « Est » lorsque la quantité vendue est supérieure à 50.

 

Utilisez la formule :

{=MIN(SI(B2:B10 = "Est"; SI(C2:C10> 50; D2:D10)))}

  • Le critère 1 est que le prix doit provenir de la région « Est ».
  • Le critère 2 est le prix lorsque la quantité est supérieure à 50.

Explication :

  • SI(C2:C10> 50 ; D2:D10) renvoie un tableau de valeurs « FAUX » et de valeurs de prix où la quantité est supérieure à 50 : {FAUX; 3030; 1080; 1530; FAUX; FAUX; 5200; 900; 1770}.
  • SI(B2:B10 = "Est" ; SI(C2:C10> 50 ; D2:D10)) renvoie un tableau de valeurs de prix restantes où la région est « Est » : {FAUX; 3030; FAUX; 1530; FAUX; FAUX; FAUX; FAUX; 1770}.
  • La fonction MIN trouve la valeur minimale du tableau retourné, qui sera la valeur prix minimum requise.
  • INous avons fait correspondre la plage (B2:B10) avec la valeur « Est » et la quantité (C2:C10) supérieure à 50, ce qui renvoie le minimum de la plage de prix (D2:D10).
  • Appuyez sur Ctrl + Shift + Entrée pour obtenir le minimum de la plage comme illustré dans la capture ci-dessus.

Télécharger le fichier Excel de ce tutoriel



Tutoriel Excel