Tuto Excel : Compter le nombre de caractères dans une cellule

Tuto Excel : Compter le nombre de caractères dans une cellule

Dans ce tutoriel, nous expliquons comment compter les caractères dans Excel. Vous apprendrez à utiliser des formules Excel pour retourner le nombre total de caractères contenues dans une seule cellule ou dans une plage de cellules. Vous découvrirez également des formules pour ne compter que des caractères spécifiques dans une cellule ou dans une plage de cellules.

Excel vous offre diverses fonctions étonnantes que vous pouvez utiliser pour manipuler et travailler avec des données de texte. Par exemple, dans certaines situations, vous pouvez avoir besoin de calculer le nombre total de caractères dans une cellule ou plage de cellules ou, dans d’autres cas, vous pouvez chercher à calculer le nombre de fois qu'un caractère spécifique apparaît dans une cellule. Comme la plupart de vous peuvent le deviner, vous pouvez utiliser la fonction NBCAR qui a pour objectif le calcul du nombre de caractères dans une cellule. Cependant, vous aurez besoin d’une combinaison de formules pour faire le reste comme nous le verrons plus loin dans les exemples.

Table des matières

Comment compter tous les caractères d'une cellule

Comment compter tous les caractères dans une plage

Comment compter des caractères spécifiques dans une cellule

Comment compter des caractères spécifiques dans une plage

Comment compter tous les caractères d'une cellule

Si votre objectif est de simplement calculer le nombre total de tous les caractères que vous avez dans une cellule de la feuille de calcul, il vous suffit d’utiliser la fonction NBCAR. Cette dernière est une fonction intégrée dans Excel qui est classée en tant que chaîne ou texte. Elle sert normalement à compter les caractères et renvoyer le nombre de caractères dans une chaîne de texte. En d’autres termes, elle mesure la longueur de la chaîne spécifiée.

La syntaxe de la fonction NBCAR est comme suit :

NBCAR(Texte)

Comme vous pouvez le voir, cette fonction prend un seul argument. Cet argument peut être fourni sous forme d’un texte entre guillemets ou sous forme d’une référence de cellule à une cellule contenant le texte. Prenons par exemple le jeu de données indiqué dans la capture ci-dessous :

Nous souhaitons maintenant compter le nombre total de caractères dans chaque cellule. Pour ce faire, entrez la formule ci-dessous dans la cellule « B2 » et appliquez-la aux restes des cellules de la colonne « B » :

=NBCAR(A2)

La capture ci-dessous montre le résultat que nous avons obtenu :

Utilisée seule, la fonction NBCAR peut ne pas être d’une grande utilité, mais lorsque vous la combinez avec d'autres formules, elle vous aidera à réaliser des choses merveilleuses. Vous pouvez par exemple l’utiliser avec d’autres fonctions pour obtenir le nombre de mots dans une cellule ou séparer le prénom et le nom.

Une note que vous devez garder dans l’esprit, est que la fonction NBCAR calculera le nombre de tous les caractères dans une cellule. Ainsi, elle comptera également tout caractère spécial, les chiffres, les signes de ponctuation et les espaces (de début, de fin et de doubles espaces entre les mots). En prenant tous cela en considération, il est toujours possible que vous obteniez un résultat erroné au cas où vous auriez des espaces supplémentaires dans la cellule ou dans la chaine de texte passée en argument.

Prenons l’exemple dans la capture ci-dessous, comme vous pouvez le voir, la fonction NBCAR renvoie « 11 » pour le texte de la cellule « A2 », alors qu'elle aurait dû être « 5 » comme le nom « Amina » est composé uniquement de 5 caractères. Mais comme vous l’avez peut-être remarqué, nous avons ajouté des caractères d'espace supplémentaire avant et après le texte, et puisque la fonction NBCAR considère ces espaces nous avons obtenu un résultat erroné :

Comment faire alors pour éviter que des espaces supplémentaires ne soient comptés ? La solution est très simple, vous devez d'abord supprimer ces espaces avant de calculer le nombre de caractères. Ne vous inquiétez pas, vous n’allez pas le faire manuellement mais en utilisant l’une des fonctions puissantes d’Excel. Elle s’agit de la fonction SUPPRESPACE qui permet de supprimer les espaces de début, de fin et doubles. Ensuite, vous devrez passer le résultat de la fonction SUPPRESPACE à la fonction NBCAR pour obtenir le nombre réel de caractères. La formule ci-dessous fera ceci :

=NBCAR(SUPPRESPACE(A2))

Et voilà ! maintenant la formule calcul bien le nombre de caractères sans compter les espaces.

Comment compter tous les caractères dans une plage

Maintenant, si votre objectif est de compter le nombre total de caractères contenus dans plusieurs cellules (plage), la solution la plus simple est d’obtenir le nombre de caractères contenus dans chaque cellule de cette plage et puis à additionner ces nombres. Par exemple, pour compter le nombre de caractères dans les cellules « A2:A6 » nous utiliserons la formule qui suit :

=NBCAR(A2) + NBCAR(A3) + NBCAR(A4) + NBCAR(A5) + NBCAR(A6)

Au lieu d’utiliser l’opérateur d’addition, vous pouvez également utiliser la fonction SOMME comme suit :

=SOMME(NBCAR(A2); NBCAR(A3); NBCAR(A4); NBCAR(A5); NBCAR(A6))

L’utilisation de ces deux formules est très simple et ne demande pas beaucoup d’efforts. Cependant, nous vous recommandons de les utiliser uniquement pour un petit nombre de cellules, sinon, il sera déroutant de taper la formule pour un grand nombre de cellules.

Si vous souhaitez compter le nombre de caractères pour une plus grande plage, vous feriez mieux d’utiliser une fonction plus puissante comme la fonction SOMMEPROD. Cette dernière multiplie les tableaux et renvoie la somme des produits. Vous pouvez ainsi passer la référence de toute la plage au lieu de taper les références des cellules une par une. La syntaxe da formule est comme suit :

=SOMMEPROD(NBCAR(plage))

Ci-dessous la formule à utiliser pour compter le nombre de caractères dans la plage « A2:A6 » :

=SOMMEPROD(NBCAR(A2:A6))

Maintenant, expliquons comment fonctionne cette formule. La fonction NBCAR calcule le nombre de caractère dans la chaîne de texte pour chaque cellule de la plage « A2:A6 » et les renvoie sous forme de tableau de nombres. Ce tableau est transmis à la fonction SOMMEPROD qui additionne les valeurs et renvoie le nombre total de caractères.

Vous pouvez voir les valeurs retournées par la fonction NBCAR, sélectionnez-la dans la formule et puis appuyez sur la touche « F9 ». Dans notre exemple, un tableau de 5 nombres représentant les nombres de caractères dans les cellules « A2 » à « A6 » :

Maintenant, si vous vous demandez pourquoi vous ne pouvez pas utiliser la fonction SOMME au lieu de SOMMEPROD, la raison en est qu'il s'agit d'un tableau et la fonction SOMMEPROD peut gérer un tableau, mais la fonction SOMME ne le peut pas.

Pourtant, Vous pouvez également utiliser la fonction SOMME en combinaison avec la fonction NBCAR comme suit :

=SOMME(NBCAR(A2:A6))

Mais pour utiliser cette formule vous devez appuyer sur le raccourci « Ctrl + Shift + Entrée » au lieu d’un simple « Enter » pour la transformer en formule matricielle. Comme vous le voyez dans la capture d'écran ci-dessous, cette formule renvoie le même nombre total de caractères dans la plage « A2:A6 » :

N’oubliez toujours pas que la fonction Excel NBCAR compte absolument tous les caractères de chaque cellule, y compris les lettres, les chiffres, les signes de ponctuation, les symboles spéciaux et tous les espaces.

Comment compter des caractères spécifiques dans une cellule

Dans cette section vous allez découvrir une autre astuce concernant le nombre de caractères dans une cellule. Nous vous expliquerons comment compter le nombre de fois qu'un caractère spécifique existe dans une chaîne de texte. En fait, parfois on cherche à compter uniquement les occurrences d'une lettre, d'un chiffre ou d'un symbole spécial spécifique au lieu de compter tous les caractères d'une cellule.

Par exemple, combien de fois la lettre « S » apparaît dans le mot « Suisse », habituellement, vous pouvez les compter à la main, mais systématiquement, vous devez utiliser une technique un peu intelligente en suivant les étapes ci-dessous :

  • Tout d’abord, vous devez calculer le nombre de caractères du mot « Suisse » (6 caractères).
  • Ensuite, supprimez les lettres « S » et comptez le nombre des caractères restants (3 caractères).
  • Finalement, soustrayez la longueur ajustée de la longueur d'origine.

En suivant ce processus vous pouvez conclure avec précision que le nombre de fois où la lettre « » apparaît dans le mot « Suisse » est de trois. Ce processus peut être implémenté sous forme de formule en utilisant la fonction NBCAR avec SUBSTITUE comme suit :

=NBCAR(cellule) - NBCAR(SUBSTITUE(cellule ; caractère ; ""))

Pour voir la formule en application, considérons l’exemple de la section précédente. Nous souhaitons maintenant compter le nombre de fois que la lettre « a » apparaît dans chaque cellule de la plage « A2:A6 ».

Les noms se trouvent dans la colonne « a » commençant par la cellule « A2 », nous allons donc saisir la formule qui suit dans la cellule « B2 » et puis l’appliquer aux restes des cellules de la colonne « B » :

=NBCAR(A2) - NBCAR(SUBSTITUE(A2 ; "a" ; ""))

Expliquons maintenant comment fonctionne la formule pas à pas :

  • Nous avons commencé par calculer la longueur totale de la chaîne en « A2 » en utilisant la formule NBCAR(A2) ;
  • Ensuite, nous avons utilisé la formule SUBSTITUE(A2 ; "a" ; "") afin de supprimer toutes les occurrences de la lettre « a » dans la cellule « A2 » et les remplacer par des chaînes vides ("").
  • NBCAR(SUBSTITUE(A2 ; "a" ; "") : nous avons ensuite passé la formule SUBSTITUE à la fonction NBCAR pour compter la longueur de la chaîne retournée sans le caractère « ».
  • Finalement, nous avons utilisé l’opérateur de soustraction pour soustraire la longueur de la chaîne sans "a" de la longueur de chaîne totale.

La formule en totale renvoie le nombre de caractères supprimés (lettre « a »), qui représente le nombre total d'occurrences de ces caractères dans la cellule.

Remarque : dans la formule ci-dessus, nous avons passé directement la lettre « a » comme argument à la fonction SUBSTITUE. Généralement, il s’agit d’une méthode acceptée mais il est toujours préférable de taper la lettre souhaitée dans une cellule, puis passer la référence de cette cellule à la formule. Le grand avantage de cette méthode et que vous pourrez compter les occurrences de tout autre caractère saisi dans cette cellule sans avoir à modifier votre formule à chaque fois.

Analysons maintenant le résultat que nous avons obtenu dans notre exemple :

Vous avez peut-être remarqué en premier lieu que la cellule A2 contient 2 occurrences de la lettre « A », une en majuscule et une autre en minuscule. Cependant la formule dans la cellule « B2 » a retourné « 1 ». D’où vient le problème ?  En fait, la fonction SUBSTITUE d'Excel est sensible à la casse, et par conséquent, la formule ci-dessus est également sensible à la casse. Ainsi, dans le cas de la cellule « A2 » la cellule n'a compté que les caractères minuscules car nous avons fourni "a" à la fonction SUBSTITUE.

Si ce n’est ce que vous cherchiez, vous pouvez modifier la formule pour calculer le nombre de caractères insensible à la casse et renvoyer ainsi « » au lieu de « 1 » dans l’exemple de la cellule « A2 ». L’astuce consiste à intégrer la fonction MAJUSCULE dans la formule SUBSTITUE afin de convertir toute la chaine de texte en majuscules avant d'exécuter la substitution.

Par exemple, pour compter les éléments « A » et « a » dans les cellules « A2:A6 », utilisez cette formule :

=NBCAR(A2) - NBCAR(SUBSTITUE(MAJUSCULE(A2); "A"; ""))

Comme vous pouvez le voir dans la capture ci-dessus, la formule prend maintenant en considération toutes les lettres « A » et compte parfaitement les occurrences en majuscules et en minuscules. N’oubliez pas de saisir le caractère majuscule dans la formule.

Une alternative de l’utilisation de la fonction MAJUSCULE consiste à utiliser des fonctions de substitution imbriquées :

=NBCAR(A2) - NBCAR(SUBSTITUE(SUBSTITUE(A2; "A"; ""); "a"; "")

Dans la formule ci-dessus, nous avons codé en dur le caractère que nous souhaitons compter, mais vous pouvez également le mettre dans une cellule, puis utiliser la référence de cette cellule dans la formule. Cela rend les choses plus pratiques car la formule serait mise à jour à chaque fois que vous modifierez le texte de la cellule.

Comment compter des caractères spécifiques dans une plage

Maintenant que vous savez comment faire pour compter les caractères spécifiques dans une cellule, vous souhaiterez peut-être améliorer la formule pour afin qu’elle renvoie le nombre de fois qu’un certain caractère apparaît dans toute une plage de cellules. Ceux qui ont bien suivi le tutoriel pourraient peut-être deviner comment faire ! nous allons utiliser la formule qui compte le nombre d’occurrences d’un caractère spécifique dans une cellule (que nous venons de voir dans l'exemple précédent). La différence est que nous allons envoyer cette formule en tant qu’argument à la fonction SOMMEPROD qui peut gérer les tableaux. La formule générée est comme suit :

SOMMEPROD(NBCAR(plage) - NBCAR(SUBSTITUE(plage; caractère ; "")))

Appliquons cette formule sur notre exemple. Nous obtenons la formule ci-dessous :

=SOMMEPROD(NBCAR(A2:A6) - NBCAR(SUBSTITUE(A2:A6; "A"; "")))

De même, vous pouvez utiliser la formule SOMME ci-dessous pour compter les caractères dans la plage :

=SOMME(NBCAR(A2:A6) - NBCAR(SUBSTITUE(A2:A6; "A"; "")))

Comme vous pouvez le voir dans la capture ci-dessus, la fonction SOMME renvoie le même résultat. Assurez-vous simplement d’appuyer sur le raccourci Ctrl + Shift + Entrée car contrairement à SOMMEPROD, qui est conçu pour traiter les tableaux, SOMME ne peut gérer les tableaux que lorsqu'on l’utilise dans une formule matricielle.

Comme nous l’avons fait pour les autres exemples, vous pouvez taper le caractère dans une cellule et passer la référence de cette cellule à la formule au lieu de le coder en dur. Par exemple, nous avons tapé le caractère « » dans la cellule B2 et nous avons utilisé sa référence dans la formule comme suit :

=SOMMEPROD(NBCAR(A2:A6) - NBCAR(SUBSTITUE(A2:A6; B2; "")))

Conclusion

Et voilà, notre tutoriel arrive à sa fin, vous savez maintenant comment compter les caractères dans Excel à l'aide de la fonction NBCAR et d’autres. Rappelez-vous que Lorsque vous utilisez la fonction NBCAR vous comptez également les espaces vides et tout autre type de caractères. La fonction NBCAR comptera et retournera tout le texte tout ce que vous avez spécifié dans les données. Si vous voulez savoir comment compter le nombre d’occurrence plutôt que le nombre de caractères individuels, vous trouverez quelques formules utiles dans ce tutoriel.

Lire aussi

  • Tuto Excel : réduire le nombre de caractère dans une cellule
  • Excel : comment compter le nombre de cellule comprise entre deux valeurs
  • Tutoriel Excel : compter et additionner les cellules par couleur ?
  • Tutoriel Excel : supprimer les espaces dans les cellules
  • Tuto Excel : créer une plage nommée dynamique
  • Tuto Excel : utiliser les fonctions NB et NBVAL
  • Comment compter le nombre d'occurrences dans Excel
  • Tutoriel Excel

    x