Excel : comment calculer l'age à partir de la date de naissance
Ce tutoriel explique différentes façons d'obtenir l'âge dans Excel. Vous apprendrez une poignée de formules pour calculer l'âge en nombre d'années complètes et obtenir l'âge exact en années, mois et jours à la date d'aujourd'hui ou à une date particulière.
Pour l'instant, Excel n'a pas de fonction spéciale qui vous permet de calculer l'âge en utilisant la date de naissance. Cependant, ce n'est pas parce qu'il n'y a pas de fonction spéciale que vous ne pouvez pas le faire dans Excel. Avec la combinaison appropriée de quelques fonctions, il est possible de connaître rapidement l’âge à partir de la date de naissance.
Cépendant, il existe plusieurs outils en ligne (comme on peut y voir par là) qui permettent de trouver instantanément la durée qui s'est écoulée entre deux dates, a travers une de début et une de fin, vous obtiendrez facilement la durée qui s'est écoulée entre-temps en années, mois, jours, heures, minutes ou secondes.
Ce tutoriel concerne Excel 2016 pour Windows. Vous avez une version différente ? Pas de problème, vous pouvez toujours suivre exactement les mêmes étapes.
Table des matières
Comment calculer l'âge à partir de la date de naissance dans Excel ?
Formule Excel de base pour calculer l'âge en années
Calculer l'âge avec la fonction FRACTION.ANNEE
Calculer l'âge avec la fonction DATEDIF
Calculer l'âge en années, mois et jours
Formules spécifiques pour calculer l'âge dans Excel
Comment calculer l'âge à une date spécifique dans Excel ?
Calculer l'âge dans une certaine année
Découvrez une date à laquelle une personne atteint N ans
Calculer l'âge à partir du jour, du mois et de l'année dans différentes cellules
Comment mettre en évidence certains âges (inférieurs ou supérieurs à un âge spécifique) ?
Comment calculer l'âge à partir de la date de naissance dans Excel ?
Dans la vie de tous les jours, la question "Quel âge avez-vous?" implique généralement une réponse indiquant combien d'années vous avez été en vie. Dans Microsoft Excel, vous pouvez créer une formule pour calculer un âge exact en années, mois, jours, heures et même en minutes. Mais soyons traditionnels et apprenons d'abord à calculer l'âge à partir de la date de naissance en années.
Formule Excel de base pour calculer l'âge en années
Comment déterminez-vous normalement votre l'âge ? Simplement en soustrayant la date de naissance de la date actuelle. Cette formule d'âge conventionnelle peut également être utilisée dans Excel.
En supposant qu'une date de naissance se trouve dans la cellule A1, la formule pour calculer l'âge en années se présente comme suit: =(AUJOURDHUI()-A1)/365
La première partie de la formule (AUJOURDHUI()-A1) renvoie la différence entre la date actuelle et la date de naissance en jours, puis vous divisez ce nombre par 365 pour obtenir le nombre d'années.
La formule est évidente et facile à retenir, cependant, il y a un petit problème. Dans la plupart des cas, il renvoie un nombre décimal comme illustré dans la capture d'écran ci-dessus.
Pour afficher le nombre d'années complètes, utilisez la fonction ENT pour arrondir une décimale à l'entier le plus proche :
=ENT((AUJOURDHUI()-A1) / 365)
L'utilisation de cette formule d'âge dans Excel produit des résultats assez précis, mais pas parfaits. La division par le nombre moyen de jours dans une année fonctionne bien la plupart du temps, mais parfois, l'âge est erroné. Par exemple, si quelqu'un est né le 29 février et est aujourd'hui le 28 février, la formule rendra la personne plus âgée d'un jour.
Comme alternative, vous pouvez diviser par 365,25 au lieu de 365 car chaque quatrième année à 366 jours. Cependant, cette approche n'est pas parfaite non plus. Par exemple, si vous calculez l'âge d'un enfant qui n'a pas encore vécu une année bissextile, la division par 365,25 produit un résultat erroné.
Dans l'ensemble, la soustraction de la date de naissance de la date actuelle fonctionne très bien dans la vie normale, mais n'est pas l'approche idéale dans Excel. Plus loin dans ce tutoriel, vous apprendrez quelques fonctions spéciales qui permettent de calculer l'âge sans erreur quelle que soit l'année.
Calculer l'âge avec la fonction FRACTION.ANNEE
Un moyen plus fiable de convertir une date de naissance en âge dans Excel est d'utiliser la fonction FRACTION.ANNEE qui renvoie la fraction de l'année, c'est-à-dire le nombre de jours entiers entre deux dates.
La syntaxe de la fonction FRACTION.ANNEE est la suivante :
FRACTION.ANNEE(date_début ; date_fin ; [base])
Les deux premiers arguments sont évidents et ne nécessitent guère d'explication supplémentaire. La base est un argument facultatif qui définit la base de calcul de jours à utiliser.
Pour créer une formule d'âge parfaitement vraie, fournissez les valeurs suivantes à la fonction FRACTION.ANNEE :
- Date_début : date de naissance.
- Date_fin : fonction AUJOURDHUI() pour renvoyer la date du jour.
- Base : utilisez la base 1 qui indique à Excel de diviser le nombre réel de jours par mois par le nombre réel de jours par an.
Compte tenu de ce qui précède, une formule Excel pour calculer l'âge à partir de la date de naissance est la suivante: FRACTION.ANNEE(date de naissance ;AUJOURDHUI() ; 1)
En supposant que la date de naissance se trouve dans la cellule A1, la formule prend la forme suivante: =FRACTION.ANNEE(A1;AUJOURDHUI();1)
Comme dans l'exemple précédent, le résultat de la fonction FRACTION.ANNEE est également un nombre décimal. Pour résoudre ce problème, utilisez la fonction ARRONDI.INF avec 0 dans le dernier argument car vous ne voulez pas de décimales.
Voici donc une formule FRACTION.ANNEE améliorée pour calculer l'âge dans Excel: =ARRONDI.INF(FRACTION.ANNEE(A1;AUJOURDHUI();1);0)
Calculer l'âge avec la fonction DATEDIF
Une autre façon de convertir la date de naissance en âge dans Excel consiste à utiliser la fonction DATEDIF. Cependant, cette fonction est un peu unique car Excel ne vous aidera pas à remplir la formule une fois que vous l'avez tapée. Mais ne vous inquiétez pas, la fonction fonctionnera très bien une fois que vous aurez utilisé les bons paramètres.
Voici sa syntaxe :
DATEDIF(date_début ; date_fin ; unité)
Paramètres :
- « date_début » : la date de début.
- «date_fin » : la date de fin.
- «Unité» : l'unité de temps à utiliser (années, mois ou jours).
La fonction « DATEDIF » peut renvoyer la différence entre deux dates dans différentes unités de temps telles que les années, les mois et les jours, selon la valeur que vous fournissez dans l'argument unité :
- Y : renvoie le nombre d'années complètes entre les dates de début et de fin.
- M : renvoie le nombre de mois complets entre les dates.
- D : renvoie le nombre de jours entre les deux dates.
- YM : renvoie des mois, en ignorant les jours et les années.
- MD : renvoie la différence en jours, en ignorant les mois et les années.
- YD : renvoie la différence en jours, en ignorant les années.
Puisque nous visons à calculer l'âge en années, nous utilisons l'unité "y": DATEDIF(date de naissance ;AUJOURDHUI() ; "y")
Dans cet exemple, la date de naissance se trouve dans la cellule A1 et vous référencez cette cellule dans votre formule d'âge : =DATEDIF(A1;AUJOURDHUI();"y")
Aucune fonction d'arrondi supplémentaire n'est nécessaire dans ce cas car une formule DATEDIF avec l'unité "y" calcule le nombre d'années complètes.
Calculer l'âge en années, mois et jours
Comme vous venez de le voir, calculer l'âge comme le nombre d'années complètes que la personne a vécues est facile, mais ce n'est pas toujours suffisant. Si vous voulez connaître l'âge exact, c'est-à-dire le nombre d'années, de mois et de jours entre la date de naissance d'une personne et la date actuelle, écrivez 3 fonctions DATEDIF différentes :
- Pour obtenir le nombre d'années: =DATEDIF(A1;AUJOURDHUI();"Y")
- Pour obtenir le nombre de mois: =DATEDIF(A1;AUJOURDHUI();"YM")
- Pour obtenir le nombre de jours: =DATEDIF(A1;AUJOURDHUI();"MD")
Où A1 est la cellule contenant la date de naissance.
Et puis, concaténez les fonctions ci-dessus dans une seule formule, comme ceci :
=DATEDIF(A1;AUJOURDHUI();"Y")&DATEDIF(A1;AUJOURDHUI();"YM")& DATEDIF(A1;AUJOURDHUI();"MD")
La formule ci-dessus renvoie 3 nombres (années, mois et jours) concaténés dans une seule chaîne de texte, comme indiqué dans la capture d'écran ci-dessous :
Cela n'a pas beaucoup de sens! Pour rendre les résultats plus significatifs, séparez les nombres par des virgules et définissez la signification de chaque valeur:
=DATEDIF(A1;AUJOURDHUI();"Y") & " Années, "&DATEDIF(A1;AUJOURDHUI();"YM") & " Mois, "& DATEDIF(A1;AUJOURDHUI();"MD")& " Jours"
Le résultat semble bien meilleur maintenant.
La formule fonctionne très bien, mais vous pouvez l'améliorer encore plus en masquant les valeurs nulles. Pour cela, utilisez la fonction SI pour vérifier les 0, une pour chaque DATEDIF:
=SI(DATEDIF(A1;AUJOURDHUI();"Y")=0;"";DATEDIF(A1;AUJOURDHUI();"Y") & " Années, ")& SI(DATEDIF(A1;AUJOURDHUI();"YM")=0;"";DATEDIF(A1;AUJOURDHUI();"YM") & " Mois, ")& SI(DATEDIF(A1;AUJOURDHUI();"MD")=0;"";DATEDIF(A1;AUJOURDHUI();"MD")& " Jours")
La capture d'écran suivante illustre la formule d'âge Excel finale en action - elle renvoie l'âge en années, mois et jours, affichant uniquement des valeurs non nulles:
Si vous recherchez une formule Excel pour calculer l'âge en années et mois, prenez la formule ci-dessus et supprimez le dernier bloc SI(DATEDIF()) qui calcule les jours.
Formules spécifiques pour calculer l'âge dans Excel
Les formules génériques de calcul de l'âge décrites ci-dessus fonctionnent très bien dans la plupart des cas. Dans certaines situations, cependant, vous pouvez avoir besoin de quelque chose de très spécifique. Bien sûr, il n'est pas possible de couvrir tous les scénarios, mais les exemples suivants vous donneront quelques idées sur la façon dont vous pouvez modifier une formule d'âge en fonction de votre tâche particulière.
Comment calculer l'âge à une date spécifique dans Excel ?
Si vous voulez connaître l'âge d'une personne à une certaine date, utilisez la formule d'âge DATEDIF décrite ci-dessus, mais remplacez la fonction AUJOURDHUI() dans le 2e argument par la date spécifique.
En supposant que la date de naissance est en A1, la formule suivante retournera l'âge au 30 Mai 2020 :
=DATEDIF(A1;"30/05/2020";"Y") & " Années, "& DATEDIF(A1;"30/05/2020";"YM") & " Mois, " & DATEDIF(A1;"30/05/2020";"MD") &" Jours "
Pour rendre votre formule d'âge plus flexible, vous pouvez entrer la date dans une cellule et référencer cette cellule dans votre formule :
=DATEDIF(A1;A2;"Y") & " Années, "& DATEDIF(A1;A2;"YM") & " Mois, " & DATEDIF(A1;A2;"MD") &" Jours "
Où A1 est la date de naissance et A2 est la date à laquelle vous souhaitez calculer l'âge.
Calculer l'âge dans une certaine année
Cette formule est utile dans les situations où la date complète de calcul n'est pas définie et où vous ne connaissez que l'année.
Supposons que vous travaillez avec une base de données médicales et que votre objectif est de connaître l'âge des patients au moment où ils ont subi le dernier examen médical complet.
En supposant que les dates de naissance figurent dans la colonne A commençant par la ligne 2 et que l'année du dernier examen médical figure dans la colonne B, la formule de calcul de l'âge est la suivante :
=DATEDIF(A2;DATE(B2;1; 1); "y")
Étant donné que la date exacte de l'examen médical n'est pas définie, vous utilisez la fonction DATE avec un argument de date et de mois arbitraire, par ex. DATE(B2;1;1).
La fonction DATE extrait l'année de la cellule B2, établit une date complète à l'aide des numéros de mois et de jour que vous avez fournis (1er février dans cet exemple) et transmet cette date à DATEDIF. En conséquence, vous obtenez l'âge du patient au 1er janvier d'une année donnée.
Découvrez une date à laquelle une personne atteint N ans
Supposons que votre ami soit né le 10 février 2001. Comment savez-vous à quelle date il termine ses 40 ans ? Habituellement, vous ajouteriez simplement 40 ans à la date de naissance de la personne. Dans Excel, vous faites de même en utilisant la fonction DATE :
=DATE(ANNEE(A2) + 40; MOIS(A2); JOUR(A2))
Où A2 est la date de naissance.
Au lieu de coder en dur le nombre d'années dans la formule, vous pouvez référencer une certaine cellule où vos utilisateurs peuvent entrer n'importe quel nombre d'années.
Calculer l'âge à partir du jour, du mois et de l'année dans différentes cellules
Lorsqu'une date de naissance est divisée en 3 cellules différentes (par exemple, l'année est en A2, le mois en B2 et le jour en C2), vous pouvez calculer l'âge de cette manière :
Obtenez la date de naissance en utilisant les fonctions DATE et DATEVAL :
DATE(A2; MOIS(DATEVAL(B2 & "1")) ;C2)
Intégrez la formule ci-dessus dans DATEDIF pour calculer l'âge à partir de la date de naissance en années, mois et jours :
=DATEDIF(DATE(A2; MOIS(DATEVAL(B2 & "1"));C2);AUJOURDHUI();"Y") & " Années, "&DATEDIF(DATE(A2; MOIS(DATEVAL(B2 & "1"));C2);AUJOURDHUI();"YM") & " Mois, "& DATEDIF(DATE(A2; MOIS(DATEVAL(B2 & "1"));C2);AUJOURDHUI();"MD")& " Jours"
Comment mettre en évidence certains âges (inférieurs ou supérieurs à un âge spécifique) ?
Dans certaines situations, vous devrez peut-être non seulement calculer l'âge dans Excel, mais également mettre en évidence les cellules qui contiennent des âges inférieurs ou supérieurs à un âge particulier.
Si votre formule de calcul de l'âge renvoie le nombre d'années complètes, vous pouvez créer une règle de mise en forme conditionnelle régulière basée sur une formule simple comme celles-ci:
- Pour mettre en évidence des âges égaux ou supérieurs à 18 : = $B2>= 18
- Pour mettre en évidence les moins de 18 ans : =$B2
Où B2 est la cellule la plus haute de la colonne Age (sans inclure l'en-tête de colonne).
Mais que se passe-t-il si votre formule affiche l'âge en années et mois, ou en années, mois et jours ? Dans ce cas, vous devrez créer une règle basée sur une formule DATEDIF qui calcule l'âge à partir de la date de naissance en années.
En supposant que les dates de naissance figurent dans la colonne A commençant par la ligne 2, les formules sont les suivantes :
Pour mettre en évidence les moins de 18 ans (jaune) :
=DATEDIF($A2;AUJOURDHUI(); "Y")
Pour mettre en évidence les âges entre 18 et 65 ans (vert) :
=ET(DATEDIF($A2; AUJOURDHUI(); "Y")>= 18; DATEDIF($A2; AUJOURDHUI(); "Y")
Pour mettre en évidence les âges de plus de 65 ans (bleu) :
=DATEDIF($A2; AUJOURDHUI(); "Y")> 65
Pour créer des règles basées sur les formules ci-dessus, sélectionnez les cellules ou les lignes entières que vous souhaitez mettre en surbrillance, accédez à l'onglet Accueil > groupe Styles, puis cliquez sur Mise en forme conditionnelle> Nouvelle règle…> Utilisez une formule pour déterminer pour quelles cellules le format sera appliqué.
Les étapes détaillées peuvent être trouvées ici : Maitriser la mise en forme conditionnelle.
C'est ainsi que vous calculez l'âge dans Excel. J'espère que les formules ont été faciles à apprendre et que vous les essayerez dans vos feuilles de travail.
Article publié le 18 Août 2021par Hanane Mouqqadim